Build: Use interface targets for inheriting flags and definitions

* Remove the usage of global flags and definitions set through the CMAKE_CXX_FLAGS variable. * Use cmake target compile features for setting the CXX standard automatically. * Make C++14 globally available in the project * Closes #21033 (cherry picked from commit e60c1f84a7)
2026-01-16 07:30:42 +01:00 · 2017-10-31 01:29:51 +01:00
parent af7352118b
commit ff35262a3a
22 changed files with 264 additions and 76 deletions
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -55,6 +55,7 @@ if( NOPCH )
  set(USE_SCRIPTPCH 0)
 endif()

+include(ConfigureBaseTargets)
 include(CheckPlatform)

 include(GroupSources)
--- a/cmake/compiler/clang/settings.cmake
+++ b/cmake/compiler/clang/settings.cmake
@@ -1,29 +1,48 @@
 # Set build-directive (used in core to tell which buildtype we used)
-add_definitions(-D_BUILD_DIRECTIVE='"${CMAKE_BUILD_TYPE}"')
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")

 if(WITH_WARNINGS)
-  set(WARNING_FLAGS "-W -Wall -Wextra -Winit-self -Wfatal-errors -Wno-mismatched-tags")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} -Woverloaded-virtual")
+  target_compile_options(trinity-warning-interface
+    INTERFACE
+      -W
+      -Wall
+      -Wextra
+      -Winit-self
+      -Wfatal-errors
+      -Wno-mismatched-tags
+      -Woverloaded-virtual)
+
  message(STATUS "Clang: All warnings enabled")
 endif()

 if(WITH_COREDEBUG)
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -g3)
+
  message(STATUS "Clang: Debug-flags set (-g3)")
 endif()

 # -Wno-narrowing needed to suppress a warning in g3d
 # -Wno-deprecated-register is needed to suppress 185 gsoap warnings on Unix systems.
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -Wno-narrowing -Wno-deprecated-register")
-set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DDEBUG=1")
+target_compile_options(trinity-compile-option-interface
+  INTERFACE
+    -Wno-narrowing
+    -Wno-deprecated-register)
+
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -DDEBUG=1)

 if (BUILD_SHARED_LIBS)
  # -fPIC is needed to allow static linking in shared libs.
  # -fvisibility=hidden sets the default visibility to hidden to prevent exporting of all symbols.
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC -fvisibility=hidden")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC -fvisibility=hidden")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -fPIC
+      -fvisibility=hidden)

  # --no-undefined to throw errors when there are undefined symbols
  # (caused through missing TRINITY_*_API macros).
--- a/cmake/compiler/gcc/settings.cmake
+++ b/cmake/compiler/gcc/settings.cmake
@@ -1,5 +1,7 @@
 # Set build-directive (used in core to tell which buildtype we used)
-add_definitions(-D_BUILD_DIRECTIVE='"${CMAKE_BUILD_TYPE}"')
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")

 set(GCC_EXPECTED_VERSION 6.3.0)

@@ -7,37 +9,47 @@ if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_EXPECTED_VERSION)
  message(FATAL_ERROR "GCC: TrinityCore requires version ${GCC_EXPECTED_VERSION} to build but found ${CMAKE_CXX_COMPILER_VERSION}")
 endif()

-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
-message(STATUS "GCC: Enabled c++11 support")
-
-set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=gnu99")
-message(STATUS "GCC: Enabled C99 support")
-
 if(PLATFORM EQUAL 32)
  # Required on 32-bit systems to enable SSE2 (standard on x64)
-  set(SSE_FLAGS "-msse2 -mfpmath=sse")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${SSE_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${SSE_FLAGS}")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -msse2
+      -mfpmath=sse)
 endif()
-add_definitions(-DHAVE_SSE2 -D__SSE2__)
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -DHAVE_SSE2
+    -D__SSE2__)
 message(STATUS "GCC: SFMT enabled, SSE2 flags forced")

 if( WITH_WARNINGS )
-  set(WARNING_FLAGS "-W -Wall -Wextra -Winit-self -Winvalid-pch -Wfatal-errors")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} -Woverloaded-virtual")
+  target_compile_options(trinity-warning-interface
+    INTERFACE
+      -W
+      -Wall
+      -Wextra
+      -Winit-self
+      -Winvalid-pch
+      -Wfatal-errors
+      -Woverloaded-virtual)
+
  message(STATUS "GCC: All warnings enabled")
 endif()

 if( WITH_COREDEBUG )
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -g3)
+
  message(STATUS "GCC: Debug-flags set (-g3)")
 endif()

 if (BUILD_SHARED_LIBS)
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC -fvisibility=hidden -Wno-attributes")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC -fvisibility=hidden -Wno-attributes")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -fPIC
+      -fvisibility=hidden
+      -Wno-attributes)

  # Should break the build when there are TRINITY_*_API macros missing
  # but it complains about missing references in precompiled headers.
--- a/cmake/compiler/icc/settings.cmake
+++ b/cmake/compiler/icc/settings.cmake
@@ -1,18 +1,28 @@
-# Set build-directive (used in core to tell which buildtype we used)
-add_definitions(-D_BUILD_DIRECTIVE="'${CMAKE_BUILD_TYPE}'")
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")

 if(PLATFORM EQUAL 32)
-  add_definitions(-axSSE2)
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -axSSE2)
 else()
-  add_definitions(-xSSE2)
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -xSSE2)
 endif()

 if( WITH_WARNINGS )
-  add_definitions(-w1)
+  target_compile_options(trinity-warning-interface
+    INTERFACE
+      -w1)
+
  message(STATUS "ICC: All warnings enabled")
 endif()

 if( WITH_COREDEBUG )
-  add_definitions(-g)
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -g)
  message(STATUS "ICC: Debug-flag set (-g)")
 endif()
--- a/cmake/compiler/mingw/settings.cmake
+++ b/cmake/compiler/mingw/settings.cmake
@@ -2,26 +2,41 @@
 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

 # Set build-directive (used in core to tell which buildtype we used)
-add_definitions(-D_BUILD_DIRECTIVE=\\"${CMAKE_BUILD_TYPE}\\")
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")

 if(PLATFORM EQUAL 32)
  # Required on 32-bit systems to enable SSE2 (standard on x64)
-  set(SSE_FLAGS "-msse2 -mfpmath=sse")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${SSE_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${SSE_FLAGS}")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -msse2
+      -mfpmath=sse)
 endif()
-add_definitions(-DHAVE_SSE2 -D__SSE2__)
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -DHAVE_SSE2
+    -D__SSE2__)
 message(STATUS "GCC: SFMT enabled, SSE2 flags forced")

 if( WITH_WARNINGS )
-  set(WARNING_FLAGS "-W -Wall -Wextra -Winit-self -Winvalid-pch -Wfatal-errors")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} -Woverloaded-virtual")
+  target_compile_options(trinity-warning-interface
+    INTERFACE
+      -W
+      -Wall
+      -Wextra
+      -Winit-self
+      -Winvalid-pch
+      -Wfatal-errors
+      -Woverloaded-virtual)
+
  message(STATUS "GCC: All warnings enabled")
 endif()

 if( WITH_COREDEBUG )
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      -g3)
+
  message(STATUS "GCC: Debug-flags set (-g3)")
 endif()
--- a/cmake/compiler/msvc/settings.cmake
+++ b/cmake/compiler/msvc/settings.cmake
@@ -7,6 +7,19 @@ if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS MSVC_EXPECTED_VERSION)
  message(FATAL_ERROR "MSVC: TrinityCore requires version ${MSVC_EXPECTED_VERSION} (MSVC 2015 Update 3) to build but found ${CMAKE_CXX_COMPILER_VERSION}")
 endif()

+# CMake sets warning flags by default, however we manage it manually
+# for different core and dependency targets
+string(REGEX REPLACE "/W[0-4] " "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
+# Search twice, once for space after /W argument,
+# once for end of line as CMake regex has no \b
+string(REGEX REPLACE "/W[0-4]$" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
+string(REGEX REPLACE "/W[0-4] " "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
+string(REGEX REPLACE "/W[0-4]$" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
+
+target_compile_options(trinity-warning-interface
+  INTERFACE
+    /W3)
+
 # set up output paths ofr static libraries etc (commented out - shown here as an example only)
 #set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
@@ -15,7 +28,10 @@ if(PLATFORM EQUAL 64)
  # This definition is necessary to work around a bug with Intellisense described
  # here: http://tinyurl.com/2cb428.  Syntax highlighting is important for proper
  # debugger functionality.
-  add_definitions("-D_WIN64")
+  target_compile_definitions(trinity-compile-option-interface
+    INTERFACE
+      -D_WIN64)
+
  message(STATUS "MSVC: 64-bit platform, enforced -D_WIN64 parameter")

 else()
@@ -23,7 +39,9 @@ else()
  set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /LARGEADDRESSAWARE")
  message(STATUS "MSVC: Enabled large address awareness")

-  add_definitions(/arch:SSE2)
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      /arch:SSE2)
  message(STATUS "MSVC: Enabled SSE2 support")

  set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} /SAFESEH:NO")
@@ -33,18 +51,27 @@ endif()
 # Set build-directive (used in core to tell which buildtype we used)
 # msbuild/devenv don't set CMAKE_MAKE_PROGRAM, you can choose build type from a dropdown after generating projects
 if("${CMAKE_MAKE_PROGRAM}" MATCHES "MSBuild")
-  add_definitions(-D_BUILD_DIRECTIVE=\\"$(ConfigurationName)\\")
+  target_compile_definitions(trinity-compile-option-interface
+    INTERFACE
+      -D_BUILD_DIRECTIVE="$(ConfigurationName)")
 else()
  # while all make-like generators do (nmake, ninja)
-  add_definitions(-D_BUILD_DIRECTIVE=\\"${CMAKE_BUILD_TYPE}\\")
+  target_compile_definitions(trinity-compile-option-interface
+    INTERFACE
+      -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")
 endif()

 # multithreaded compiling on VS
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
+target_compile_options(trinity-compile-option-interface
+  INTERFACE
+    /MP)

 if((PLATFORM EQUAL 64) OR (NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0.23026.0) OR BUILD_SHARED_LIBS)
  # Enable extended object support
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      /bigobj)
+
  message(STATUS "MSVC: Enabled increased number of sections in object files")
 endif()

@@ -55,36 +82,60 @@ endif()
 # http://blogs.msdn.com/b/vcblog/archive/2015/08/06/new-in-vs-2015-zc-throwingnew.aspx
 if(NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0.23026.0))
  # makes this flag a requirement to build TC at all
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zc:throwingNew")
+  target_compile_options(trinity-compile-option-interface
+    INTERFACE
+      /Zc:throwingNew)
 endif()

 # Define _CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES - eliminates the warning by changing the strcpy call to strcpy_s, which prevents buffer overruns
-add_definitions(-D_CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES)
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES)
 message(STATUS "MSVC: Overloaded standard names")

 # Ignore warnings about older, less secure functions
-add_definitions(-D_CRT_SECURE_NO_WARNINGS)
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_CRT_SECURE_NO_WARNINGS)
 message(STATUS "MSVC: Disabled NON-SECURE warnings")

 # Ignore warnings about POSIX deprecation
-add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
+target_compile_definitions(trinity-compile-option-interface
+  INTERFACE
+    -D_CRT_NONSTDC_NO_WARNINGS)
+
 message(STATUS "MSVC: Disabled POSIX warnings")

 # Ignore specific warnings
 # C4351: new behavior: elements of array 'x' will be default initialized
 # C4091: 'typedef ': ignored on left of '' when no variable is declared
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4351 /wd4091")
+target_compile_options(trinity-warning-interface
+  INTERFACE
+    /wd4351
+    /wd4091)

 if(NOT WITH_WARNINGS)
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4996 /wd4355 /wd4244 /wd4985 /wd4267 /wd4619 /wd4512")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4996 /wd4355 /wd4244 /wd4985 /wd4267 /wd4619 /wd4512")
+  target_compile_options(trinity-warning-interface
+    INTERFACE
+      /wd4996
+      /wd4355
+      /wd4244
+      /wd4985
+      /wd4267
+      /wd4619
+      /wd4512)
+
  message(STATUS "MSVC: Disabled generic compiletime warnings")
 endif()

 if (BUILD_SHARED_LIBS)
  # C4251: needs to have dll-interface to be used by clients of class '...'
  # C4275: non dll-interface class ...' used as base for dll-interface class '...'
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4251 /wd4275")
+  target_compile_options(trinity-warning-interface
+    INTERFACE
+      /wd4251
+      /wd4275)
+
  message(STATUS "MSVC: Enabled shared linking")
 endif()

@@ -97,7 +148,10 @@ set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zm500")
 # Enable and treat as errors the following warnings to easily detect virtual function signature failures:
 # 'function' : member function does not override any base class virtual member function
 # 'virtual_function' : no override available for virtual member function from base 'class'; function is hidden
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /we4263 /we4264")
+target_compile_options(trinity-warning-interface
+  INTERFACE
+    /we4263
+    /we4264)

 # Disable incremental linking in debug builds.
 # To prevent linking getting stuck (which might be fixed in a later VS version).
--- a/cmake/macros/ConfigureBaseTargets.cmake
+++ b/cmake/macros/ConfigureBaseTargets.cmake
@@ -0,0 +1,62 @@
+# Copyright (C) 2008-2017 TrinityCore <http://www.trinitycore.org/>
+#
+# This file is free software; as a special exception the author gives
+# unlimited permission to copy and/or distribute it, with or without
+# modifications, as long as this notice is preserved.
+#
+# This program is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+
+# An interface library to make the target com available to other targets
+add_library(trinity-compile-option-interface INTERFACE)
+
+# An interface library to make the target features available to other targets
+add_library(trinity-feature-interface INTERFACE)
+
+target_compile_features(trinity-feature-interface
+  INTERFACE
+    cxx_alias_templates
+    cxx_auto_type
+    cxx_constexpr
+    cxx_decltype
+    cxx_decltype_auto
+    cxx_final
+    cxx_lambdas
+    cxx_generic_lambdas
+    cxx_variadic_templates
+    cxx_defaulted_functions
+    cxx_nullptr
+    cxx_trailing_return_types
+    cxx_return_type_deduction)
+
+# An interface library to make the warnings level available to other targets
+# This interface taget is set-up through the platform specific script
+add_library(trinity-warning-interface INTERFACE)
+
+# An interface amalgamation which provides the flags and definitions
+# used by the dependency targets.
+add_library(trinity-dependency-interface INTERFACE)
+target_link_libraries(trinity-dependency-interface
+  INTERFACE
+    trinity-compile-option-interface
+    trinity-feature-interface)
+
+if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
+  target_compile_options(trinity-dependency-interface
+    INTERFACE
+      /W0)
+else()
+  target_compile_options(trinity-dependency-interface
+    INTERFACE
+      -w)
+endif()
+
+# An interface amalgamation which provides the flags and definitions
+# used by the core targets.
+add_library(trinity-core-interface INTERFACE)
+target_link_libraries(trinity-core-interface
+  INTERFACE
+    trinity-compile-option-interface
+    trinity-feature-interface
+    trinity-warning-interface)
--- a/cmake/platform/unix/settings.cmake
+++ b/cmake/platform/unix/settings.cmake
@@ -32,5 +32,7 @@ elseif(CMAKE_C_COMPILER MATCHES "icc")
 elseif(CMAKE_C_COMPILER MATCHES "clang" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  include(${CMAKE_SOURCE_DIR}/cmake/compiler/clang/settings.cmake)
 else()
-  add_definitions(-D_BUILD_DIRECTIVE='"${CMAKE_BUILD_TYPE}"')
+  target_compile_definitions(trinity-compile-option-interface
+    INTERFACE
+      -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")
 endif()
--- a/dep/CMakeLists.txt
+++ b/dep/CMakeLists.txt
@@ -8,14 +8,6 @@
 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

-if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
-  string(REGEX REPLACE "/W[0-4] " "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
-  string(REGEX REPLACE "/W[0-4] " "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
-  add_definitions(/W0)
-else()
-  add_definitions(-w)
-endif()
-
 add_subdirectory(threads)

 if(SERVERS OR TOOLS)
--- a/dep/CascLib/CMakeLists.txt
+++ b/dep/CascLib/CMakeLists.txt
@@ -54,6 +54,8 @@ target_include_directories(casc
      ${CMAKE_SOURCE_DIR}/dep)

 target_link_libraries(casc
+  PRIVATE
+    trinity-dependency-interface
  PUBLIC
    zlib)

--- a/dep/bzip2/CMakeLists.txt
+++ b/dep/bzip2/CMakeLists.txt
@@ -30,6 +30,10 @@ else()
    PUBLIC
      ${CMAKE_CURRENT_SOURCE_DIR})

+  target_link_libraries(bzip2
+    PRIVATE
+      trinity-dependency-interface)
+
  set_target_properties(bzip2
    PROPERTIES
      FOLDER
--- a/dep/efsw/CMakeLists.txt
+++ b/dep/efsw/CMakeLists.txt
@@ -73,6 +73,8 @@ if (BUILD_SHARED_LIBS)
      ${CMAKE_CURRENT_SOURCE_DIR}/src)

  target_link_libraries(efsw
+    PRIVATE
+      trinity-dependency-interface
    PUBLIC
      threads
      ${OPTIONAL_MAC_LINK_LIBRARIES})
--- a/dep/fmt/CMakeLists.txt
+++ b/dep/fmt/CMakeLists.txt
@@ -46,6 +46,10 @@ target_compile_definitions(fmt
    -DFMT_USE_DELETED_FUNCTIONS
    -DFMT_USE_EXTERN_TEMPLATES)

+target_link_libraries(fmt
+  PRIVATE
+    trinity-dependency-interface)
+
 set_target_properties(fmt
  PROPERTIES
    FOLDER
--- a/dep/g3dlite/CMakeLists.txt
+++ b/dep/g3dlite/CMakeLists.txt
@@ -61,6 +61,8 @@ target_include_directories(g3dlib
    ${CMAKE_CURRENT_SOURCE_DIR}/include)

 target_link_libraries(g3dlib
+  PRIVATE
+    trinity-dependency-interface
  PUBLIC
    zlib
    threads)
--- a/dep/gsoap/CMakeLists.txt
+++ b/dep/gsoap/CMakeLists.txt
@@ -23,6 +23,8 @@ target_compile_definitions(gsoap
    -DWITH_OPENSSL)

 target_link_libraries(gsoap
+  PRIVATE
+    trinity-dependency-interface
  PUBLIC
    openssl)

--- a/dep/jemalloc/CMakeLists.txt
+++ b/dep/jemalloc/CMakeLists.txt
@@ -66,6 +66,8 @@ if(CMAKE_SYSTEM_NAME MATCHES "Linux" AND NOT NOJEM)
      -D_REENTRAN)

  target_link_libraries(jemalloc
+    PRIVATE
+      trinity-dependency-interface
    PUBLIC
      threads
      valgrind)
--- a/dep/protobuf/CMakeLists.txt
+++ b/dep/protobuf/CMakeLists.txt
@@ -57,13 +57,6 @@ else()
  )
 endif()

-if (UNIX)
-  # Enable the default unix export behaviour for protobuf so we don't
-  # need to patch it's sources.
-  string(REPLACE "-fvisibility=hidden" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
-  string(REPLACE "-fvisibility=hidden" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
-endif()
-
 add_library(protobuf ${protobuf_STAT_SRCS})

 target_include_directories(protobuf
@@ -73,6 +66,8 @@ target_include_directories(protobuf
    ${CMAKE_CURRENT_SOURCE_DIR}/tc_custom)

 target_link_libraries(protobuf
+  PRIVATE
+    trinity-default-interface
  PUBLIC
    threads)

--- a/dep/recastnavigation/Detour/CMakeLists.txt
+++ b/dep/recastnavigation/Detour/CMakeLists.txt
@@ -24,6 +24,8 @@ target_include_directories(Detour
    ${CMAKE_CURRENT_SOURCE_DIR}/Include)

 target_link_libraries(Detour
+  PRIVATE
+    trinity-dependency-interface
  PUBLIC
    zlib)

--- a/dep/recastnavigation/Recast/CMakeLists.txt
+++ b/dep/recastnavigation/Recast/CMakeLists.txt
@@ -28,6 +28,8 @@ target_include_directories(Recast
    ${CMAKE_CURRENT_SOURCE_DIR}/Include)

 target_link_libraries(Recast
+  PRIVATE
+    trinity-dependency-interface
  PUBLIC
    zlib)

--- a/dep/zlib/CMakeLists.txt
+++ b/dep/zlib/CMakeLists.txt
@@ -43,6 +43,10 @@ else()
    PUBLIC
      ${CMAKE_CURRENT_SOURCE_DIR})

+  target_link_libraries(zlib
+    PRIVATE
+      trinity-dependency-interface)
+
  set_target_properties(zlib
      PROPERTIES
        FOLDER
--- a/src/common/CMakeLists.txt
+++ b/src/common/CMakeLists.txt
@@ -66,6 +66,7 @@ target_link_libraries(common
  PRIVATE
    process
  PUBLIC
+    trinity-core-interface
    boost
    fmt
    g3dlib
--- a/src/server/proto/PrecompiledHeaders/protoPCH.cpp
+++ b/src/server/proto/PrecompiledHeaders/protoPCH.cpp
@@ -1 +0,0 @@
-#include "protoPCH.h"